Arduinoで近距離無線通信 RFID-RC522 NFC

+-----------+----------+--+---------------------+
|           |RFID-RC522|方| Arduino Uno         |
|           |(MFRC522) |向|                     |
+-----------+----------+  +---------------------+
| Signal    | Pin      |  | Pin                 |
+===========+==========+==+=====================+
| RST/Reset | RST      |←| Digital 9 [1]_      |
+-----------+----------+--+---------------------+
| SPI SS    | SDA [3]_ |←| Digital 10 [2]_     |
+-----------+----------+--+---------------------+
| SPI MOSI  | MOSI     |←| Digital 11 / ICSP-4 |
+-----------+----------+--+---------------------+
| SPI MISO  | MISO     |→| Digital 12 / ICSP-1 |
+-----------+----------+--+---------------------+
| SPI SCK   | SCK      |←| Digital 13 / ICSP-3 |
+-----------+----------+--+---------------------+

void loop() {
    // Mifareカードの確認（新しいカードが無ければ終了し、loop関数を繰り返す）
    if ( ! mfrc522.PICC_IsNewCardPresent()) return;

    // Mifareカードのデータ読み込み（読み取れなければ終了し、loop関数を繰り返す）
    if ( ! mfrc522.PICC_ReadCardSerial()) return;

    // Mifareカード(もしくはMifareタグ)のUID情報の表示
    Serial.print("Card UID:");                  // MifareカードのUIDの表示
    dump_byte_array(mfrc522.uid.uidByte, mfrc522.uid.size);
    Serial.println();
    Serial.print("PICC type: ");                // Mifareカードのタイプ表示
    byte piccType = mfrc522.PICC_GetType(mfrc522.uid.sak);
    Serial.println(mfrc522.PICC_GetTypeName(piccType));

    // Mifareカードのタイプが対応しているかどうかを確認
    if (    piccType != MFRC522::PICC_TYPE_MIFARE_MINI
        &&  piccType != MFRC522::PICC_TYPE_MIFARE_1K
        &&  piccType != MFRC522::PICC_TYPE_MIFARE_4K) {
        Serial.println("This sample only works with MIFARE Classic cards.");
        return;
    }

    // Mifareカードの先頭から2番目のセクタ(セクタ番号#1)へデータを書き込むサンプル
    byte sector         = 1;                    // 書き込みを実行するセクタ番号 #1
    byte blockAddr      = 4;                    // セクタ #1の先頭ブロック番号 #4
    byte dataBlock[]    = {                     // 書き込みデータ
        0x01, 0x02, 0x03, 0x04,                 //  1,  2,   3,  4,
        0x05, 0x06, 0x07, 0x08,                 //  5,  6,   7,  8,
        0x08, 0x09, 0xff, 0x0b,                 //  8,  9, 255, 11,
        0x0c, 0x0d, 0x0e, 0x0f                  // 12, 13,  14, 15
    };
    byte trailerBlock   = 7;                    // セクタ#1のトレーラブロック番号#7
    byte status;
    byte buffer[18];
    byte size = sizeof(buffer);

    // Mifareカードへ暗号キーAを使って認証を実行
    // 暗証キーは MIFARE_Key keyで定義される6バイトのコード。
    // 新品のMifareカードの初期値 FF FF FF FF FF FFをsetup関数で代入済
    Serial.println("Authenticating using key A...");
    status = mfrc522.PCD_Authenticate(
        MFRC522::PICC_CMD_MF_AUTH_KEY_A,        // 暗号キーAを使った認証
        trailerBlock,                           // トレーラブロック番号(#7)を指定
        &key,                                   // 暗号キー(FF FF FF FF FF FF)を指定
        &(mfrc522.uid)                          // 対象となるMifareカードのUIDを指定
    );
    if (status != MFRC522::STATUS_OK) return;   // 認証に成功しなかった場合は終了

    // Mifareカード内のセクタ(#1)データを読み取って表示
    Serial.println("Current data in sector:");
    mfrc522.PICC_DumpMifareClassicSectorToSerial(&(mfrc522.uid), &key, sector);
    Serial.println();

    // Mifareカード内のブロック(#4)データを読み取って変数bufferへ代入
    Serial.print("Reading data from block "); Serial.println(blockAddr);
    mfrc522.MIFARE_Read(blockAddr, buffer, &size);
    Serial.print("Data in block "); Serial.print(blockAddr); Serial.println(":");
    dump_byte_array(buffer, 16); Serial.println(); Serial.println();

    // Mifareカードへ暗号キーBを使って認証を実行
    // 暗証キーは暗号キーAと同じ変数MIFARE_Key keyおよび同じ値を使用
    Serial.println("Authenticating again using key B...");
    status = mfrc522.PCD_Authenticate(
        MFRC522::PICC_CMD_MF_AUTH_KEY_B,        // 暗号キーBを使った認証
        trailerBlock,                           // トレーラブロック番号(#7)を指定
        &key,                                   // 暗号キー(FF FF FF FF FF FF)を指定
        &(mfrc522.uid)                          // 対象となるMifareカードのUIDを指定
    );
    if (status != MFRC522::STATUS_OK) return;   // 認証に成功しなかった場合は終了

    // Mifareカード内のブロック(#4)へ変数dataBlockのデータを書き込む
    Serial.print("Writing data into block "); Serial.println(blockAddr);
    dump_byte_array(dataBlock, 16); Serial.println();
    mfrc522.MIFARE_Write(blockAddr, dataBlock, 16);

    // 正しく書き込まれたかどうかを確認するためのMifareカードからの読み込み
    Serial.print("Reading data from block "); Serial.println(blockAddr);
    status = mfrc522.MIFARE_Read(blockAddr, buffer, &size);
    Serial.print("Data in block "); Serial.print(blockAddr); Serial.println(":");
    dump_byte_array(buffer, 16); Serial.println();
        
    // 正しく書き込まれたかどうかを確認
    Serial.println("Checking result...");
    byte count = 0;
    for (byte i = 0; i < 16; i++) if (buffer[i] == dataBlock[i]) count++;
    if (count == 16) Serial.println("Success :-)");
    else Serial.println("Failure, no match :-(");
    Serial.println();
        
    // Mifareカード内のセクタ(#1)データを読み取って表示
    Serial.println("Current data in sector:");
    mfrc522.PICC_DumpMifareClassicSectorToSerial(&(mfrc522.uid), &key, sector);
    Serial.println();

    mfrc522.PICC_HaltA();                       // PICCの停止
    mfrc522.PCD_StopCrypto1();                  // PCD暗号化の停止
}