[IchigoJam メニューへ戻る]

ボクにもわかるIchigoJam用
導通テスター・簡易抵抗測定器の製作

IchigoJamで抵抗値を測定している様子
IchigoJamで抵抗値を測定している様子

はじめに

 このページではIchigoJamにブレッドボード用ジャンパーワイヤーを接続するだけで実行可能な導通テスターの製作方法を紹介します。3kΩ〜3MΩくらいまで、なんとなく目安の値が表示されるので、半田付け後の導通チェッカーとして活用することが出来るでしょう。
 なお、本機は「測定器」ではありません。測定結果は誤差の多い目安値です。

IchigoJam用導通テスターの特徴

  • ワイヤーを接続するだけで導通チェッカー
  • 簡易抵抗値測定機能(約3kΩ〜3MΩ)
  • 簡易電圧測定機能(約3mV〜3300mV)
  • 抵抗値に合わせた棒グラフ表示(対数表示)
  • 導通時にブザー音・LED点灯
  • I2C小型液晶への表示も可能(テレビが無くても抵抗値の確認が可能)

IchigoJamとワイヤーだけで導通チェッカー

 ハードウェアはブレッドボード用ジャンパーワイヤーをIchigoJamのBTN端子とGND端子に接続するだけです。IchigoJamのBTN端子には1MΩのプルアップ抵抗が取り付けられています。この1MΩをリファレンスとして抵抗値を測ります。
 2台目のIchigoJam製作時やIchigoJam半田付け教室などで活用できると思います。

ハードウェアの製作

 以下にブレッドボード用ジャンパーを接続する場所を記します。

IC
Pin
IchigoJam
Pin名
IchigoJam
Pin位置
接続
13 BTN CN4 下から2番目 ジャンパー赤
8 GND CN4 下から7番目 ジャンパー黒

IchigoJamで抵抗値を測定している様子
IchigoJamにジャンパーワイヤーを接続した様子(ハードはこれだけで完成)

ADCの値を読み取るコマンド

 ジャンパーを接続したら下記のコマンドを実行してみて下さい。そしてジャンパーワイヤーを100kΩなどの抵抗の両端に接触させてみて下さい。

FORM=2TOM+3:CLS:?ANA():NEXT

 コマンドを実行すると画面の左上の値が変化することが分かると思います。「?ANA()」がBTN端子のアナログ値を読み取って表示するコマンドです。

FOR M=2 TO M+3 : CLS : ? ANA() : NEXT
FORはNEXTまでの処理を繰り返す命令です。変数Mに初期値2を代入しM+3になるまで1ずつ加算して繰り返します。Mが増えるたびに上限も増えるので、繰り返し処理を続けます。しかし、Mが32768になった時に終了します。「FOR M=32700 TO M+3:? M:NEXT」として確認してみると良いでしょう。M=2やM+3としているのは打ち間違えないようにするためです。

導通テスター・簡易抵抗値測定プログラム

 基本プログラムは以下のようになります。100番台はアナログ入力から得られた値を電圧値[mV]に変換する処理部です。200番台は得られた電圧値から抵抗値[Ω]に変換する処理部です。300番台は表示用です。グラフは、最大値から除算を繰り返し、1未満になるまで#文字を出力することで表現します。

IchigoJam用導通テスター(IchigoJam BASIC Ver 1.0.1〜1.2.3で動作確認済)
1 cls:?"Resistance":?"Checker"

100 'ADC
110 A=ANA()
120 if A>1022 then V=3300:A=1023:goto 200
130 if A>101 then V=A*32/10:goto 200
140 if A>10 then V=A*323/100:goto 200
150 V=A*3226/1000

200 'R Ohm
210 if A>929 then R=9999:goto 300
220 if A>327 then R=A*10/(1023-A)*100:goto 300
230 if A>32 then R=A*100/(1023-A)*10:goto 300
240 R=A*1000/(1023-A)

300 'PRINT
310 lc 0,0
320 ?"R:";R;" kOhm";
330 ?"       ":I=R/40
340 if I ?"#";:I=I/2:goto 340
350 ?"       ":?"V:";V;" mV";
360 ?"       ":I=A/4
370 if I ?"#";:I=I/2:goto 370
380 ?"       ":if R=0 beep:led 1 else led 0
390 goto 100

 I2C液晶と組み合わせたい場合は以下の行を追加してください。IchigoJam BASIC バージョン1.0.1以降、ファームウェアの正式リリースが行われるたびに、動作確認を行っています。

10 gosub800
390 gosub900:goto100
800 'LCD INIT
810 poke#700,64,0,2,#C0,57,17,#70,86,#6C,56,12
820 ifi2cw(62,#701,1,#704,5)?"E"
830 wait12
840 ifi2cw(62,#701,1,#709,2)?"E"
900 'LCD OUT
910 ifi2cw(62,#701,1,#702,1)+i2cw(62,#700,1,#900,8)+i2cw(62,#701,1,#703,1)+i2cw(62,#700,1,#920,8)?"E"
920 return

 実行すると小型液晶に抵抗値と棒グラフ(#の文字の数で抵抗の大きさを示す)を表示します。

I2C液晶に結果を表示した時の様子
I2C液晶に結果を表示した時の様子

抵抗値を測ってみよう

 それでは早速、測ってみましょう。本テスターとは別の測定対象となる機器(ハンダ付け製作直後のIchigoJamなど)を準備します。2台のIchigoJamが登場するので、以下の説明では、「テスターとなるIchigoJam」、「測定対象となるIchigoJam」を読み分けて下さい。
 測定対象の機器には電源やビデオケーブル、USBなどを接続してはいけません。測定対象がIchigoJamの場合、測定対象のコネクタCN5の両端(一番上と一番下)の端子を測定してみてください。測定対象がIchigoJam Uの場合の正常値は1MΩ以上(1000kΩ以上)、IchigoJam SやTの場合は100kΩ以上です。
 次に測定対象のVCCとGNDに接続します。測定対象がIchigoJam Uの場合の正常値は10kΩ以上、IchigoJam SやTの場合は100kΩ以上です。3kΩ以下であったり、テスター側のブザーやLEDが作動した場合は、測定対象の配線がショートしている可能性があります。
 他にも接続が不安な区間を測ってみましょう。通電があればLEDが点灯し、ブザー音が鳴ります。

 下図は本ページの内容を「IchigoJam Sの組み立てかた」で紹介したページです。図の右上のIchigoJamが本ページで製作したテスターで、中央のIchigoJamがハンダ付け製作直後の測定対象を想定しています。テスターピンを当てている部分が、基板の裏側から見たコネクタCN5の位置です。

ハンダトラブル処方箋
「ボクにもわかるIchigoJam Sの組み立てかた」より

使用上の注意点

  • 本テスターの測定値は誤差の多い目安値です。
  • ジャンパー黒(GND)ピンはUSBのGNDと共通です。
  • 測定対象がUSBのGNDを経由した場合、GNDが同電位になり、正しく測定できないことがあります。
  • 抵抗値を測定する場合は電圧を入力しないようにしてください。
  • 電圧値も測定できます。3.3Vを超えないようにしてください。


掲載情報について

  • こどもパソコン IchigoJamを用いた電子工作、応用回路、BASICプログラム等を紹介しています。
  • 当ページの著作権は国野亘が所有します。複製・改変については以下の規定に従ってください。
  • 合理的な手段による著作権表示が必要です。少なくとも「国野亘」の文字を含んでください。
  • 個人利用及び20歳以下を対象にした教育目的での利用については複製・改変・再配布が可能です。
  • FacebookグループIchigoJam-FANでの利用については複製・改変・再配布が可能です。
  • その他の目的での利用については、原則として個別に当方の承諾を受ける必要があります。
  • IchigoJam は株式会社 jig.jp の登録商標です。当ページは jig.jp社の作成物ではありません。
  • 当ページの背景画像はライセンス CC BY https://pcn.club/ に基づいて改変したものです。
  • 背景画像中のIchigoJamロゴは CC BY https://ichigojam.net/ に基づいて改変したものです。
  • 当ページの作成にあたりFacebookグループIchigoJam-FANの情報を参照しました。
  • 当ウェブサイトの内容や情報については、ご自身の責任でご利用ください。
    製作品などで事故が発生した場合であっても当方は一切の補償をいたしません。

IchigoJam メインメニューへ戻る