ボクにもわかる
IchigoJam用サンプルプログラム
I2C接続RTCを使った置き時計の製作

はじめに

　このページでは maxim integrated 製のI2C接続RTC IC DS1307を使った置き時計を製作するためのハードウェア製作とIchigoJam用サンプルプログラムについて紹介します。合計3つのハードウェア製作例を紹介しますが、何れも同じRTC ICを用います。

本ページ内のコンテンツ：

RTC DS1307 [DS1307+]

　DS1307は、Maxim Integrated 社のI2C接続のリアルタイムクロックICです。ICは秋月電子通商などで300円前後で販売されています。
　電源電圧は通常動作用に5V、バックアップ動作用に3Vの両方が必要です。
　このICは動作電圧がバックアップ電池の電圧の1.3倍を超えた時に通常動作を行い、1.3倍以下の条件でバックアップ動作に切り替わります。また、通常のバックアップ用リチウム電池3Vの初期電圧が3.3Vなので、マージンを含めて4.5V以上の動作電圧が必要となります。

ハードウェアの製作

　ここではブレッドボード上に製作します。本ICのピン配列を下表に示します。

　クリスタルにはRTC用として販売されている32.768kHzのタイプを使用します。極性はありません。
　3V電源にはスーパーキャパシタ（電気二重層コンデンサ）とIchigoJamの3.3V電源を使用します。キャパシタをRTC IC DS1307の3番ピンと4番ピンとの間に接続します。極性があるので+側を3番ピンにします。また同じ3番ピンにダイオードのカソード側（バー表示のある方）を接続し、アノード側をIchigoJamのVCCへ接続します。直列に100〜1kΩくらいの抵抗を入れた方が安全です。(実験では省略)
　I2C_SCLはIchigoJamのEX1端子へ、I2C_SDAはIN3端子へ接続します。またプルアップ抵抗10kΩを電源に接続します。

ブレッドボードの様子

IchigoJam RISC-V版 では、I2C_SCLとI2C_SDAの配列が変更になります。
CN5から配線するなどの修正が必要です。（2021/5/16 追記）

部品・ジャンパー線・接続図

	1	2	3	4	5	接続		接続	6	7	8	9	10
1				X' L	1	クリスタル1		電源（+5V）	8				+5
2					2	クリスタル2		−	7
3	C		D		3	電源（+3V）		I2C_SCL	6		C K	R
4				G N D	4	GND		I2C_SDA	5	�B			R
5								EX1
6						IN1
7						IN2
8					�B	IN3
9						IN4
10						VCC
11						GND		VCC

(準備)RTCに時刻を書き込む

　RTCのバックアップ用の電源入力に3.3V、通常動作用電源入力に5Vを入力し、下記のプログラムを動かします。
　IchigoJamに接続したキーボードから、年、月、日、時、分、秒の値を入力するとRTCに日時が書き込まれ、RTC内で時刻のカウントを開始します。

1 cls:?"SET RTC"
100 ?"---INPUT---":P=#707
110 ?"YEAR 20";:inputI:gosub700
120 ?"MONTH  ";:inputI:gosub700
130 ?"DAY    ";:inputI:gosub700
140 ?"HOUR   ";:inputI:gosub700
150 ?"MINUTE ";:inputI:gosub700
160 ?"SECOND ";:inputI:gosub700
200 ?"---SET RTC---"
210 poke#700,0:poke#704,0
220 ifi2cw(#68,#700,1,#701,7)?"ERROR"
230 END
700 'BCD ENC
710 I=I/10*16+I%10:pokeP,I
720 P=P-1
730 ifP=#704thenP=#703
740 ?hex$(I,2)
750 return

時刻表示を行う

　時刻を書き込んだら下記のプログラムを動かして動作確認してみて下さい。

new
1 'RTC
10 cls
100 lc0,0:poke#700,0
110 ifi2cr(#68,#700,1,#701,7)?"E"
120 A=#707:gosub700:?"/";
130 A=#706:gosub700:?"/";
140 A=#705:gosub700:?
150 A=#703:gosub700:?":";
160 A=#702:gosub700:?":";
170 A=#701:gosub700:?
180 wait59
190 goto100
700 'PRINT
710 S=peek(A)
720 ifA=#701letS,S&#7F
730 ifA=#702letS,S&#7F
740 S=S/16*10+S%16:ifS<10?"0";
750 printS;:return

　VIDEO 5で動かすとより大きく表示できますが、その場合は、行番号140と170の末尾の「?」を削除してください（20201/05/16・Facebook IchigoJam-FANグループ・志賀さんからのご指摘をもとに追記・動作確認済）。

　下記はI2C接続の小型液晶に対応したバージョンです。小型液晶への出力と、テレビ画面への拡大表示に対応しました。 テレビ表示部の高速化にはIchigoJam-FANグループのRuria Amanagiさんのアイデアを使わせていただきました。（それでも1回の表示に2秒ほどかかります。）

new
1 'RTC
10 cls:gosub800
100 lc0,0:poke#700,0
110 ifi2cr(#68,#700,1,#701,7)?"E"
120 A=#707:gosub700:?"/";
130 A=#706:gosub700:?"/";
140 A=#705:gosub700:?
150 A=#703:gosub700:?":";
160 A=#702:gosub700:?":";
170 A=#701:gosub700:?
180 gosub800:gosub950
190 goto100
700 'PRINT
710 S=peek(A)
720 ifA=#701letS,S&#7F
730 ifA=#702letS,S&#7F
740 S=S/16*10+S%16:ifS<10?"0";
750 printS;:return
800 'LCD INIT
810 poke#700,64,0,2,#C0,57,17,#70,86,#6C,56,12
820 ifi2cw(62,#701,1,#704,5)?"E"
830 wait12
840 ifi2cw(62,#701,1,#709,2)?"E"
900 'LCD OUT
910 ifi2cw(62,#701,1,#702,1)+i2cw(62,#700,1,#900,8)+i2cw(62,#701,1,#703,1)+i2cw(62,#700,1,#920,8)?"E"
920 return
950 'TV OUT
960 let[0],#80,#8A,#85,#8F:lc0,4:forY=0to15:forX=0to7
970 C=peek(vpeek(X,Y/8)*8+Y%8):?chr$([C>>6&3],[C>>4&3],[C>>2&3],[C&3]);
980 next:next:return

高速化

　表示に約2秒を要してしまうので、秒の表示が2秒毎に変化します。これを高速化する方法はいくつかあります。一つは変更部分だけを書き換える方法です。少し手間がかかりそうです。
　あるいは「秒」を小さな文字で表示する方法もあるでしょう。これだと簡単です。プログラムを書き換えてみましょう。行番号160の「?":";」の部分を「lc 30,18」に変更し、行番号180の「gosub 950」を「if S=0 gosub 950」に書換えてみましょう。

160 A=#702:gosub 700:lc30,18
180 gosub 800:ifS=0gosub950

低消費電力化

　上記の置き時計プログラムはI2C接続の小型液晶（AE-AQM0802）にも対応しています。このような液晶に接続した場合は、IchigoJamをより低消費電力で動かしたいと思うでしょう。さらに腕時計への応用も期待できます。
　下図はRTCの7番ピンのSQW端子から1秒周期の方形波を出力、SQW端子をプルアップ(10kΩ)し、直列コンデンサ(0.1uF)を経由することで細い負論理パルスに変換し、そのパルスをIchigoJamのBTNに入力した時の回路例です。ブレッドボードの手前の方にあるのがBTN信号用パルスに変換するためのコンデンサです。

低消費電力化実験の様子

　下記はRTCから日時を取得して液晶に表示してからSLEEPを実行するプログラムです。プログラムを入力し終えたらファイル番号0に保存してください。最初に実行する時は（液晶の初期設定（行番号830〜850）を実行するために）IchigoJamのボタンを押したまま実行し、LEDの点灯（またはブザーやテレビ表示）を確認してからボタンを放してください。
　その後、1秒周期に自動で起動してはスリープする処理を繰り返します。この繰り返し動作によってIchigoJamの消費電流(約15mA)を5分の1の3mA程度に抑えることが出来ます。（IchigoJamの起動時間が200ms、1秒間隔で繰り返す）
　しかし、I2C液晶の消費電流が1mAほどあるので、平均消費電流は4mA程度、コイン電池CR2032で動かすと、2日くらいの連続動作期間となります（試算）。

new
1 'RTC for LCD
10 cls:video0
100 lc0,0:poke#700,0
110 ifi2cr(#68,#700,1,#701,7)?"E"
120 A=#707:gosub700:?"/";
130 A=#706:gosub700:?"/";
140 A=#705:gosub700:?
150 A=#703:gosub700:?":";
160 A=#702:gosub700:?":";
170 A=#701:gosub700:?
180 gosub800
190 ifbtn()goto190
200 sleep
700 'PRINT
710 S=peek(A)
720 ifA=#701letS,S&#7F
730 ifA=#702letS,S&#7F
740 S=S/16*10+S%16:ifS<10?"0";
750 printS;:return
800 'LCD+RTC INIT
810 poke#700,64,0,2,#C0,57,17,#70,86,#6C,56,12,#07,#10
820 ifbtn()=0goto900
830 led1:beep:video1:?"INIT"
840 ifi2cw(62,#701,1,#704,5)?"E"
850 ifi2cw(#68,#70B,1,#70C,1)?"E"
860 ifbtn()goto860
870 wait10:led0
900 'LCD OUT
910 ifi2cw(62,#701,1,#709,2)?"E"
920 ifi2cw(62,#701,1,#702,1)+i2cw(62,#700,1,#900,8)+i2cw(62,#701,1,#703,1)+i2cw(62,#700,1,#920,8)?"E"
930 return

　今後の課題は1秒ごとの起動と、液晶の消費電流です。起動間隔を広げる（起動頻度を下げる）には、例えば、RTC-8564NBのような高機能なRTCへの変更し、1分間隔で動作させる方法があります。この場合、IchigoJam動作時の消費電力が上例の1/60となります。（引き換えに秒表示が出来なくなる）
　しかし、液晶の消費電流の方は今のところ対策がありません。例えば、動作周波数を下げても、あまり電流は下がりません。通常の（I2Cではない）キャラクタ液晶であれば電源をオープンにしても1分くらいは表示を維持するのですが、このキャラクタ液晶は電源をオープンにした瞬間に表示が消えてしまいます。さらに、腕時計に適したサイズの他の液晶も見当たりません。
　したがって、充電式にしたり、太陽電池と併用するなども検討する必要があるでしょう。

RTC モジュール(I2C) [M1307-12P]

　aitendo等で販売されている400円前後の格安 RTC モジュールを使用した例についても紹介します。冒頭で紹介したRTC IC DS1307と、32.768kHzのクリスタル、32KbitのEEPROM、コイン電池ホルダが予め実装された状態でモジュール化されています。ピンソケットは自分で実装する必要があります。単価が300円前後のRTC IC DS1307が実装されていて400円というのは、とてもお買い得です。

格安 RTC モジュールを使った置き時計の製作例
(青色の基板がRTCモジュール)

GROVE RTC モジュール (お奨めいたしません)

　GROVE RTCを2台、購入しましたが2台とも異常発熱し、使い物になりませんでした。また、発熱しない状態の時も1時間に1分ほど早く進むことも判明。(一般的にRTCの時刻が異常に進むのはノイズの影響です。)
　もともと、このページでは同製品を奨めようとしていたのですが、このような状態のものが2台も続いたため、方針を変更し、ブレッドボードや他のモジュールで製作することにしました。
　※注意：少なくとも私が入手した同製品は火災や火傷・事故の懸念がある危険な状態でした。十分にご注意ください。（参考情報：https://www.switch-science.com/catalog/826/）