• IchigoJamとMixJuiceで簡単接続。
• BASICスクリプトで動作します。
• クラウドサービスの設定も不要。

IoT用クラウドサービスAmbientからLED制御信号を15秒に1回、受信する。"1"を受信したらLEDが点灯し、ブザーが「ピッ」と鳴音する。"0"を受信したら消灯する。

rem LED 受信機

new
1 cls:?"Remo LED":?"Ambient"
2 'MJ GET ambidata.io/api/v2/channels/725/data?readKey=26ee8c088f61194d&n=1
7 D=7:?"data No.";D
8 W=900:?"Wait:";W/60;"s"
9 ?
100 ?"–LOOP–"
110 P=#C1D:gsb 600
120 K=asc("d"):gsb 500:C=I
130 K=asc(":"):gsb 500:L=I
140 if L=0 letL,0 else letL,1
150 K=10:gsb 500
160 if C=D led L:if L beep 2
170 ?:wait W
180 goto 100

500 'RX
510 J=0:uart0
520 I=inkey():ifI?chr$(I);
530 ifI=0andJ<30wait1:J=J+1:goto520
540 ifK<>IandJ<30goto510
550 I=inkey()-48:ifI<0orI>9ifJ<30wait1:J=J+1:goto550
560 ifI<0orI>9letI,0else?I;
570 rtn
600 'TX
610 uart1
620 ifpeek(P)<>asc("'")letP,P+1:goto620
630 P=P+1:ifpeek(P)=asc("#")?L;:goto630
640 ifpeek(P)<>0?chr$(peek(P));:goto630
650 ?:wait30:rtn

?”MJ␣APC␣SSID␣パスワード"⏎

IchigoJamへMixJuiceを接続。写真ではUSB電源をIchigoJamへ接続しているが、本来はMixJuiceへ接続したほうが動作が安定する。（このIchigoJamはMixJuiceをドライブできるように、ヒューズやコンデンサを変更済みにつき、この構成でも動作するが、通常のIchigoJamの場合は、MixJuice側へ電源を供給すること）。

制御用ウェブページ

https://bokunimo.net/ichigojam/led.html

自分専用にするには

ここに記載した方法は、自分専用ではありません。制御ウェブページのボタンを誰が操作しても、Ambientの特定のチャネル（725）へデータが送られるので、実験中に他の人が実験を行うと、同時に動作してしまいます。教室などで複数人で操作してみると楽しいかもしれませんが、実際に実用的に使用するには自分専用のアカウントが必要です。Ambient（https://ambidata.io/）にてアカウントを作成し、JavaScript版（https://bokunimo.net/ichigojam/led_js.html）のAmbientチャネルIDとライトキーを書き換えて使用すると良いでしょう。

参考資料：

SHIROのモバイル日記 [IchigoJam]7セグメントLED拡張基板

http://d.hatena.ne.jp/shiro0922/20150716/1436972916

PCN金沢 (資料)電子工作教材 4b)LED(7セグ)
http://kanazawa.pcn.club/pub/wp-content/uploads/data/4b)LED(7seg).pdf

Ambientから7セグメントLEDを制御する受信機。制御用ウェブページ（https://bokunimo.net/ichigojam/led.html）のテンキーから数字を入力すると、受信機が制御信号を受信し、同じ値が表示される。

rem 7セグメントLED 受信機

new
1 cls:?"Remo7Seg":?"Ambient"
2 'MJ GET ambidata.io/api/v2/channels/725/data?readKey=26ee8c088f61194d&n=1
3 LET[0],63,6,91,79,#66,#6D,#7D,39,#7F,#6F
7 D=7:?"data No.";D
8 W=900:?"Wait:";W/60;"s"
9 ?
100 ?"–LOOP–"
110 P=#C1D:gsb 600
120 K=asc("d"):gsb 500:C=I
130 K=asc(":"):gsb 500:L=I
150 K=10:gsb 500
160 out[L]:if L beep 2
170 ?:wait W
180 goto 100

500 'RX
510 J=0:uart0
520 I=inkey():ifI?chr$(I);
530 ifI=0andJ<30wait1:J=J+1:goto520
540 ifK<>IandJ<30goto510
550 I=inkey()-48:ifI<0orI>9ifJ<30wait1:J=J+1:goto550
560 ifI<0orI>9letI,0else?I;
570 rtn
600 'TX
610 uart1
620 ifpeek(P)<>asc("'")letP,P+1:goto620
630 P=P+1:ifpeek(P)=asc("#")?L;:goto630
640 ifpeek(P)<>0?chr$(peek(P));:goto630
650 ?:wait30:rtn

REM 7セグメントLED動作確認

10 LET[0],63,6,91,79,#66,#6D,#7D,39,#7F,#6F
20 for I=0 to 9
30 out [I]
40 wait 60
50 next

rem BTN送信機

new
1 cls:?"Remo BTN":?"Ambient"
2 'MJ GET ambidata.io/api/v2/channels/725/data?readKey=26ee8c088f61194d&n=1
3 'MJ PCT application/json
4 'MJ POST START ambidata.io/api/v2/channels/725/data
5 '{"writeKey":"ad3e53b54fe16764","d7":"#"}
6 'MJ POST END
7 D=7:?"data No.";D
8 W=900:?"Wait:";W/60;"s"
9 ?
100 ?"–LOOP–"
110 P=#C1D:gsb 600
120 K=asc("d"):gsb 500:C=I
130 K=asc(":"):gsb 500:L=I
140 if L=0 letL,0 else letL,1
150 K=10:gsb 500
160 if C=D led L:if L beep 2
170 ?:I=0
180 I=I+1:if btn()=1 gsb 400
190 if I<W/10 wait 10:goto 180
200 ?
210 goto 100

400 'BTN
410 L=!L:ledL:beep:gsb600:gsb600:gsb600:gsb600:K=-1:gosub500:letI,W/10:?
420 rtn
500 'RX
510 J=0:uart0
520 I=inkey():ifI?chr$(I);
530 ifI=0andJ<30wait1:J=J+1:goto520
540 ifK<>IandJ<30goto510
550 I=inkey()-48:ifI<0orI>9ifJ<30wait1:J=J+1:goto550
560 ifI<0orI>9letI,0else?I;
570 rtn
600 'TX
610 uart1
620 ifpeek(P)<>asc("'")letP,P+1:goto620
630 P=P+1:ifpeek(P)=asc("#")?L;:goto630
640 ifpeek(P)<>0?chr$(peek(P));:goto630
650 ?:wait30:rtn

140 if L=2 letL,1 else letL,0

Ambient

https://ambidata.io/