前回の記事
https://bokunimo.net/blog/ichigojam/99/

単3アルカリ電池で長時間の駆動が可能な IchigoJam + MixJuiceによるIoTセンサの製作例。IchigoJamとMixJuiceのスリープ機能を使用して実用的なIoTセンサの実験を行った。

IoTセンサのセンサ値をグラフ化して表示するクラウドサービスAmbient。ユーザ登録を行い、チャンネルを作成すると、①チャネルID、②リードキー、③ライトキーが発行される。このうちの①チャネルIDと③ライトキーをプログラムに組み込んで、Ambientへのデータ送信を行う。https://ambidata.io/

必要なもの

• IchigoJam U または IchigoJam T (http://ichigojam.net/)
• MixJuice (http://mixjuice.shizentai.jp/)
• 超ミニ・ブレッドボード
• 照度センサ NJL7502L
• 抵抗器 10kΩ
• ジャンパ線 橙2本、黄1本、青1本
• 電池ボックス・ジャンパワイヤ

照度センサNJL7502LのコレクタをIchigoJamのVcc（3.3V）へ、エミッタ側をIchigoJamのIN2端子へ接続する。IN2端子側には10kΩ～100kΩ程度の抵抗器を接続し、抵抗器の反対側をGNDへ接続する。さらにMixJuiceのCN4の2番ピンと4番ピンに黄色のジャンパを接続する。電源には単3電池3本を使用し、CN5へ接続する。

new
1 cls:?"Ambient":uart1
2 'MJ PCT application/json
3 'MJ POST START ambidata.io/api/v2/channels/ここにチャネルIDを書く/data
4 '{"writeKey":"ここにライトキーを書く","d1":"#"}
5 'MJ POST END
6 ?"ｱﾅﾛｸﾞ ﾆｭｳﾘｮｸ A=IN2
7 W=3000:?"ｿｸﾃｲ ｶﾝｶｸ W=";W
8 ' CC BY Wataru Kunino
rem https://bokunimo.net/ichigojam/
100 'MAIN
110 P=#C1A
120 A=ana(2):?"ana(2)=";A
130 gosub600:gosub600:gosub600:gosub600

200 'SLEEP
210 ?"MJ SLEEP ";W/60:wait30
220 ifinkey()goto220
230 led0:waitW+360,0:led1
240 ifinkey()goto240
250 ?"MJ APS":wait30
260 ifinkey()<>asc("1")goto250
270 goto100
600 'TX
610 ifpeek(P)<>asc("'")letP,P+1:goto610
620 P=P+1:ifpeek(P)=asc("#")?A;:goto620
630 ifpeek(P)<>0?chr$(peek(P));:goto620
640 ?:return

行番号110：プログラム内に書かれたMixJuice用コマンドの位置情報です。
行番号120：IN2のアナログ値を入力するコマンドです。
行番号130：MixJuice用コマンドを実行するためのgosub命令です。
行番号210：MixJuiceをスリープモードに移行します。
行番号220：キーバッファをクリアします(wait命令が適切に動かすため)。
行番号230：IchigoJamをスリープします(MixJuiceよりも6秒だけ長く)。
行番号240：キーバッファをクリアします。
行番号250：MixJuiceが動作状態かどうかを確認します。
行番号260：動作状態でなければ行番号250に戻ります。
行番号270：行番号100に戻って繰り返し処理を行います。

より長く持続させるために (追記 2016/12/4)

長期間駆動の公開実験（単4アルカリ乾電池を使用）：

https://ambidata.io/bd/board.html?id=132

修正したプログラム(赤文字部分)：

new
1 cls:?"Ambient":uart1
2 'MJ PCT application/json
3 'MJ POST START ambidata.io/api/v2/channels/ここにチャネルIDを書く/data
4 '{"writeKey":"ここにライトキーを書く","d1":"#"}
5 'MJ POST END
6 ?"ｱﾅﾛｸﾞ ﾆｭｳﾘｮｸ A=IN2
7 W=20:?"ｿｸﾃｲ ｶﾝｶｸ W=";W;" min."
8 V=W*60/63*60:video0
9 ' CC BY Wataru Kunino
rem https://bokunimo.net/ichigojam/
100 'MAIN
110 P=#C1A
120 A=0:forI=1to10:A=A+ana(2):next:?"ana(2)=";A
130 gosub600:gosub600:gosub600:gosub600

200 'MJ SLP
210 ifinkey()goto210
220 ?"MJ SLEEP ";W*60:wait30:I=0
230 ifinkey()goto230
240 ?"MJ VER":wait30
250 ifinkey()=asc("'")goto200
300 '15 SLP
310 ifinkey()goto310
320 led0:wait57,0:led1:I=I+1
330 ifI<Vgoto310
340 ifinkey()goto340
350 ?"MJ APS":wait33
360 ifinkey()<>asc("1")goto300
370 goto100
600 'TX
610 ifpeek(P)<>asc("'")letP,P+1:goto610
620 P=P+1:ifpeek(P)=asc("#")?A;:goto620
630 ifpeek(P)<>0?chr$(peek(P));:goto620
640 ?:return

主な修正部の解説：

行番号7：測定間隔を「分」の単位で入力するように修正（1分から60分）まで設定可能。

行番号8：IchigoJamのスリープ時間Vを設定。MixJuiceよりも5%だけ短くする。TV出力OFF。

行番号120：IN2端子から10回入力。変数Aは、その合計値。

行番号220：MixJuiceをスリープに移行する。変数Iを0にセットする。

行番号300：ここからがIchigoJamのスリープ処理。

行番号320：約1秒間だけスリープを実行する。変数Iに1を加算する。

行番号330：スリープ時間がV（秒）以上になるまで行番号310に戻る。

行番号350：ネットワークに接続されているかどうかを確認する。

照度センサ部を電池電圧の検出回路に変更：

[電池(+)]━━━━[82kΩ]━━●━━[可変抵抗47k]━━━━[GND/電池(-)]

　　　　　　　　　　　　　　　　　　　　┃

　　　　　　　　　　　　　　　　　　　　┗━━[ESPモジュールTOUTへ]

公開実験用に製作した回路。容量が単3電池の約半分となる単4電池を使用した。IchigoJamとMixJuiceには純正品を使用した。また、照度センサの代わりに電池電圧を測定するための可変抵抗器に変更。レギュレータのスタンバイ電流が大きいので、長くても1か月程度で実験が完了する見込み。この実験の結果によっては、BTN信号による割り込み起動で動作させるように変更する予定。最終的には単3で3か月は動かしたい。