カテゴリー
IchigoJam

低消費電力IchigoJamで乾電池動作のIoT温湿度センサを製作する

乾電池で長期間動作が可能なIchigoJamとMixJuiceを使って、IoT温湿度センサを製作してみました。
IchigoJam BASICには3種類の省エネ動作機能が標準装備されています。本ブログでは、下記のページで紹介した[3]Single Shot動作により、IchigoJamを低消費電力で動かします。
IchigoJam スリープ方法:
温湿度センサには、SiliconLabsのSi7021を使いました。Amazonで400円程度、AliExpressだと$2程度で販売されています。接続方法については、下記をご覧ください。
温湿度センサの接続方法:
https://bokunimo.net/blog/ichigojam/35/
下図はIchigoJam、ネットワーク拡張ボードMixJuice、温湿度センサSi7021、アルカリ乾電池をケースへ収容したときの様子です。
IchigoJam SまたはTへMixJuiceを接続し、単3アルカリ乾電池×3本で電源供給する。温湿度センサには、安価で高性能なSi7021を使用した。
IoT温湿度センサを、どのようなタイミングで動かしましょうか?
多くの場合、予め決めた一定の間隔で周期的に動作すれば問題ないでしょう。また、測定する時以外はIchigoJamは何もせずに、ただ次の周期を待つだけです。
そこで、IchigoJamを低消費電力動作するための方法[3]SigleShotを用いて、20分間隔で周期的に動作させてみます。
具体的には、IchigoJamのSLEEPコマンドを使って、IchigoJamの動作を停止させ、20分後にBTN信号を入力して起動するようにしました。
下図は、MixJuiceのIO16端子をIchigoJamのBTN端子へ接続し、また、IchigoJamのIN4端子をMixJuiceのRST端子へ接続したときの様子です。
①MixJuiceのIO16端子をIchigoJamのBTN端子へ接続し、また、②IchigoJamのIN4端子をMixJuiceのRST端子へ接続する。
 
MixJuiceは、予め設定した時間が経過するとIO16からリセット信号を出力します。この信号をIchigoJamのBTN端子へ入力することで、IchigoJamをスリープ状態から復帰させます。
    ① MixJuiceに設定した時間が経過するとスリープ中のIchigoJamを起動する
    ② IchigoJamが起動したら、IchigoJam BASICからMixJuiceのリセットをかける
    ③ 温度と湿度を測定し、送信を行う
    ④ 次に起動するタイミングをMixJuiceへ設定する
    ⑤ IchigoJamをスリープへ移行させる
       20分間、おやすみなさい。。。

IoT用クラウドサービスAmbientへ送信する

IoT温湿度センサが測定した温度情報と湿度情報は、IoT用クラウドサービスAmbientへ送信することで、簡単にデータの蓄積と蓄積したデータのグラフ化が可能です。
製作したIoT温湿度センサをAmbientでグラフ化したときの様子を下図に示します。
製作したIoT温湿度センサからAmbientへ温度と湿度を送信し、Ambientへ蓄積したときの様子。

IchigoJam用 IoT温湿度センサのBASICプログラム

下記は、プログラムの一例です。IchigoJamのファームウェアは、Ver 1.2.3で動作確認しました。古いファームウェアでは動作しない場合があります。
プログラム2行目のxxxxにはAmbientのチャネル番号、3行目のxxxxxxxxxxxxxxxxにはAmbientのライトキーを入力してください。
入力を終えたら、必ず「save 0」でファイル番号0へ保存してください。IchigoJamはスリープ時にプログラムが消えてしまいます。スリープ復帰後にファイル番号0のプログラムが自動的に読み込まれ、プログラムの先頭から実行します。
new
1 uart0,2:?"IoT Envセンサ PS2
2 C=xxxx
3 K="xxxxxxxxxxxxxxxx"
4 T=1200:S=1
100 @CNF
110 out 11,0:out 11,1:wait 300
120 clk:clt:uart 1,2
130 if inkey() cont
140 if tick()>1800 goto @SP

150 ?"MJ APS":wait 40
160 if inkey()<>49 goto 120
170 clk
180 ?"MJ PCT application/json"
190 gsb @RX
200 @I2
210 let[0],#3ae6,#f3,#f5
220 ?i2cw(64,#802,1);:wait 2
230 ?i2cr(64,#806,2);
240 A=([3]>>8+[3]<<8)/37-474
250 ?i2cw(64,#804,1);:wait 2
260 ?i2cr(64,#806,2)
270 B=([3]>>9+[3]<<7)/26-65
300 @TX
310 uart 1:clk
320 ?"MJ POST START ambidata.";
330 ?"io/api/v2/channels/";C;
340 ?"/data"
350 gsb @RX:uart 1
360 ?"{";chr$(34);"writeKey";
370 ? chr$(34);":";chr$(34);
380 ? str$(K);chr$(34);",";
390 ? chr$(34);"d1";chr$(34);
400 ?":";A/10;".";A%10;",";
410 ? chr$(34);"d2";chr$(34);
420 ?":";B/10;".";B%10;"}"
430 ?"MJ POST END"
440 gsb @RX
450 if !S wait T*60:goto @I2
500 @SP
510 uart 1:?"MJ SLEEP ";T
520 wait 40,0
530 if inkey() cont
540 sleep
700 @RX
710 uart 0:clt
720 I=inkey()
730 if I clt:? chr$(I);
740 if tick()<40 goto 720
750 rtn

気になる電池の持ち時間は、なんと!55日間(一例)

この回路構成とプログラムを用いて、実際に何か月間の動作が可能なのかを確認してみました。下図は、Ambientで測定しつづけた実測値です。本例では55日間の動作が確認できました。
55日間(8週間)の室温と、電池電圧を測った。温度が30℃を超えている日は、エアコンを入れていた様子が分かる。電圧は徐々に下がるが、途中から上昇しているように見える。

この測定では、湿度の替わりに電池電圧を送信してみました。ところが、途中から電圧が上がってゆく様子が見られます。これは、IchigoJamマイコンのAD変換器が電源電圧を基準にしているためで、電池電圧の低下とともにAD変換を行うための基準電圧も低下してしまったためです。
そこで、IchigoJamの入力電圧とAD変換値との関係を求めて補正してみました。入力電圧とAD変換値の関係については、別途、実測で求めました。得られた関係式を用いて、正しい電圧値へ補正した結果を下図に示します。
55日間(8週間)の電池電圧の推移。補正を行うことで、電圧が下がってゆく様子が良く分かるようになった。

無線LANアクセスポイント停止による影響

期間中のデータを確認したところ、無線LANアクセスポイントが累計2時間にわたって停止していたことが分かりました。この停止中に電池の消耗を10%ほど縮めてしまっていたようです。
とくに、2回目の1.5時間におよぶ停止は、下図からも電池の消耗が明らかです。
例えば、30秒、経過しても接続できなかったときにスリープへ移行するような対策が必要だということが分かり、プログラムを修正しました(プログラムの赤文字部分)。

むすび

乾電池で IchigoJamを動かし、IoT温湿度センサとして実用的な動作期間(55日)を達成することが出来ました。より長期間、動かしたいときは、単2や単1型に変更すると良いでしょう。
また、動作間隔を長くしたり、MixJuice上のレギュレータを低消費電力のタイプに交換したりすることで、より長い期間の動作も出来るようになるでしょう。
by ボクにもわかるIchigoJam
https://bokunimo.net/ichigojam/ (ホームページのアドレスが変わりました)
 - 
Chinese (Simplified)
 - 
zh-CN
Chinese (Traditional)
 - 
zh-TW
English
 - 
en
French
 - 
fr
German
 - 
de
Italian
 - 
it
Japanese
 - 
ja
Korean
 - 
ko
Russian
 - 
ru
Spanish
 - 
es